価格の確率的な変動を予測する波動インジケーター作ってみた

名づけるなら量子確率波動インジケーター…なんか最高にカッコイイ…

だけじゃなく、量子確率の概念を取り入れた波動分析ツール、価格の確率的な変動範囲を表示するインジケーターを作りました。

量子確率波動インジケーターだと名前が~~めんどくさい~~カッコよすぎるので、クアンタムバンドとこのページでは説明します。

ボリンジャーバンドやATRバンドみたいな波が表示されていますが、表示や計算が違います。

この波は「価格の確率的な予想移動範囲」です。

「この波の範囲内で移動する可能性が高いよ」というもです。

ボラティリティが増え価格が上下するとバンドの範囲も大きくなり、逆にレンジ相場になると小さくなります。

こんな感じ。やる気ないのが目に見えて分かりますね。

似た機能のATRバンドと比べるとこんな感じ。

ATRバンドよりもなめらかな判定になるのが特徴ですね。

それと大きな違いは△を使ったトレンド転換を示唆するサイン。

小さい△は小さな上昇トレンド。大きな△は大きな上昇トレンドの転換の可能性を表しています。

この判断基準はボラティリティ。ボラティリティが増えたところでサインが出て教えてくれます。

レンジ相場で「上か⁉下か⁉いや上だ！！！」みたいにガチャガチャしなくていいのがいいですね。

QuantumFlow Bandsパラメータ画面

ATR Period (ATR期間): デフォルト14 これは価格の変動幅を測る期間です。大きな数字にすると、より長期的な変動を捉えて安定したバンドになります。小さくすると、最近の変動に敏感に反応します。

Band Width Multiplier (バンド幅乗数):デフォルト 3.0 バンドの幅を決める数字です。大きくするとバンドが広がり、小さくすると狭くなります。広いバンドは安全策、狭いバンドは積極的なトレード向けです。

Smoothing Period (平滑化期間): デフォルト5 価格の動きを滑らかにする設定です。大きくすると滑らかになりますが反応が遅くなり、小さくすると素早く反応しますがノイズも増えます。

Show Strong Signals (強いシグナルを表示): オン大きな値動きが予想されるときに、特別なシグナル（大きめの三角形）を表示するかどうかの設定です。オンにしておくと重要なタイミングを見逃しにくくなります。

これらの設定は相場の特性やあなたの取引スタイルに合わせて調整できます。

例えば、デイトレーダーなら小さめの数値、長期投資家なら大きめの数値が適していますね。

コチラがスタイル画面。

細かく色の設定できるのでお好みで決めてください。特に小さな△と大きな△は色を変えた方が分かりやすいでね。

コチラがクアンタムバンドアラート画面。

上下で大きな△小さな△、合計4個作ってあります。

アラートメッセージを使って、自動で通貨名と時間足が出るようになっているので、とりあえずアラート付けちゃえばOKです。

QuantumFlow Bandsパラメータ画面

クアンタムバンドコード
おススメ手法

クアンタムバンドコード

//@version=5
indicator("QuantumFlow Bands™", shorttitle="QFBands", overlay=true, precision=2, scale=scale.right, linktoseries=true)

// === Main Parameters (Parameters Tab) ===
atrLength = input.int(14, "ATR Period", minval=1)
multiplier = input.float(3.0, "Band Width Multiplier", minval=0.5, step=0.1)
smoothing = input.int(5, "Smoothing Period", minval=1)
showStrongSignals = input.bool(true, "Show Strong Signals")

// === Calculations ===
atrValue = ta.atr(atrLength)
basis = ta.sma(close, smoothing)
upper = basis + atrValue * multiplier
lower = basis - atrValue * multiplier

// Trend Detection
upTrend = ta.rising(basis, 3)
downTrend = ta.falling(basis, 3)
upSignal = upTrend and not upTrend[1]
downSignal = downTrend and not downTrend[1]

// Volatility Detection
highVol = atrValue > ta.sma(atrValue, 20) * 1.2

// Strong Signal Conditions
strongUpSignal = upSignal and highVol and showStrongSignals
strongDownSignal = downSignal and highVol and showStrongSignals

// === Drawing (Style settings will appear in Style tab) ===
p1 = plot(upper, "Upper Band", color.new(#2962FF, 40), 2)
p2 = plot(lower, "Lower Band", color.new(#2962FF, 40), 2)
fill(p1, p2, color.new(#2962FF, 90))

// Normal Signals
plotshape(upSignal and not strongUpSignal, "Up Signal", shape.triangleup, location.belowbar, #00C853, size=size.tiny)
plotshape(downSignal and not strongDownSignal, "Down Signal", shape.triangledown, location.abovebar, #FF1744, size=size.tiny)

// Strong Signals
plotshape(strongUpSignal, "Strong Up Signal", shape.triangleup, location.belowbar, #00E676, size=size.small)
plotshape(strongDownSignal, "Strong Down Signal", shape.triangledown, location.abovebar, #D50000, size=size.small)

// Alerts with template variables
alertcondition(upSignal, "Up Signal", "QuantumFlow Bands™: {{ticker}} {{interval}} Up Signal")
alertcondition(downSignal, "Down Signal", "QuantumFlow Bands™: {{ticker}} {{interval}} Down Signal") 
alertcondition(strongUpSignal, "Strong Up Signal", "QuantumFlow Bands™: {{ticker}} {{interval}} Strong Up Signal")
alertcondition(strongDownSignal, "Strong Down Signal", "QuantumFlow Bands™: {{ticker}} {{interval}} Strong Down Signal")

コチラがコードです。